Hana道場【師範】のブログ

IchigoJamの徹底解説ブログ

【人気ゲーム】『プロ飛行士をめざせ!!』for IchigoJam / 『プログラミング教育マスター』がドランクドラゴンさんの番組で紹介

お久しぶりです、Hana道場師範です。

 僕も作成に協力させていただいた『プログラミング教育マスター』ドランクドラゴンさんの番組で紹介されました。

youtu.be

『プログラミング教育マスター』を手掛けた株式会社リオの浅田さんのFacebookでこんな嬉しい投稿を!

僕のブログIchigoJamで画像保存?お絵かきゲーム&イラスト保存プログラムを参考に、ねばーる君をつくってくれました。

活用してくれる方がいるということで、ブログを再開しようと思います。

f:id:hanadojo_sihan:20200828195456j:plain

Hana道場で人気のアクションゲーム『プロ飛行士をめざせ』

改造の余地も大きくとてもおすすめのプログラムです。

こちらの本でも収録されています。

『アニメーションとゲームをつくりながら学ぶ Hana道場式プログラミング』by 師範

 

【プログラム】

5 CLS:CLV:C=30
10 FOR X=10 TO 18 STEP4
20 Z=RND(19)+2:IF Z=A CONT
30 FOR Y=0 TO 22
40 LC X,Y:?CHR$(1-(Y=Z))
50 NEXT:A=Z
60 NEXT
70 LC W,Z:?"🚁"
80 WAIT3
90 LC W,Z:?" "
100 K=INKEY():IF K>28&&K<32 C=K
110 C=C-(Z>21)+(Z<1)
120 W=W+(C=29)
130 Z=Z+(C=31)-(C=30)
140 IF SCR(W,Z)!=1 GOTO70

 

<操作方法>

↑↓→で操作します。

壁にぶつかったら終了です。壁を全てくぐり抜けたらクリアです。

 

<解説>

X:壁のヨコ座標 Y:壁のタテ座標 Z:壁穴のタテ座標 A:一つ前の壁穴のタテ座標

W:ヘリのヨコ座標 Z:ヘリのタテ座標(変数のリユース

K:入力したキーのコード C:ヘリの自動移動用

5 CLS:CLV:C=30 ↑移動から開始(↑キーは30番)
10 FOR X=10 TO 18 STEP4 壁はヨコ座標10,14,18の3箇所に表示
20 Z=RND(19)+2:IF Z=A CONT 穴をランダムに決定。同じ位置ならやり直し
30  FOR Y=0 TO 22 壁はタテ座標0〜22に表示
40  LC X,Y:?CHR$(1-(Y=Z)) 壁(文字コード1番)と穴(文字コード0番)を表示
50  NEXT:A=Z 一つ前の壁穴のタテ座標を変数Aに記憶させる 
60 NEXT

70 LC W,Z:?"🚁" ヨコW,タテZの位置にヘリを表示
80 WAIT3 
90 LC W,Z:?" " ヘリを消す
100 K=INKEY():IF K>28&&K<32 C=K ←↓↑→どれかを押したらCにキーコードを代入
110 C=C-(Z>21)+(Z<1) ヘリの上下の移動制限
120 W=W+(C=29) →方向の自動移動
130 Z=Z+(C=31)-(C=30) ↑↓方向の自動移動
140 IF SCR(W,Z)!=1 GOTO70 もし 壁(1番)に当たっていなければ 70行目へ

 

<改造方法>

  1. 穴を広げる 
    40 LC X,Y:?CHR$(1-(Y=Z)-(Y=Z+1))
  2. クラッシュ演出をつける
    150 LC W,Z:?CHR$(244):BEEP50,80
  3. クリアしたら次のステージへ
    135 IF W=25 W=0:C=0:GOTO10
  4. 壁を増やす
    10 FOR X=10 TO        
  5. ステージ数を追加
  6. ステージをクリアする毎にスピードアップ
  7. 最終ステージ(第5ステージ)の演出

4〜7は自分でやってみて下さい!

『アニメーションとゲームをつくりながら学ぶ Hana道場式プログラミング』by 師範

に5〜7のプログラムが載っていますので、知りたい方はぜひお買い求めください^^

IF文や文字コードなども学ぶことができます!

CC BY shoichi1031da / @shoichi1031da

twitter.com